AppleScripting monthly events in Power Manager

–– DssW Power Manager 3.5
–– by Graham Miln
–– Copyright (c) 2007, DssW, All rights reserved
–– Wake at 5:30am

property kWakeTimeInSecondsFromMidnight : (60 * 60 * 5) + (60 * 25)

–– Shut down 30 minutes later

property kShutdownAfterSecondsFromWaking : (60 * 30)

–– Calculate the first date of this month

set firstOfTheMonth to (current date)
set day of firstOfTheMonth to 1
set time of firstOfTheMonth to kWakeTimeInSecondsFromMidnight

–– Get todays date
set today to (current date)

–– Is the first past?
if (today is greater than the firstOfTheMonth + kShutdownAfterSecondsFromWaking) then
	–– Increment the month; the month and year will roll over as required
	 set the month of the firstOfTheMonth to 1 + (month of the firstOfTheMonth)
end if

–– We now have a date and time for the next monthly trigger date
–– Create two events with known unique IDs to schedule a wake and shut down
–– Define a base event to modify and add as needed

property kEvent : {|name|:"", uniqueid:"", action:{type:""}, trigger:{type:"once", |date|:(current date)}, enabled:true}

tell application "Power Manager Scripting"

	–– Schedule a wake up event
	set myWakeEvent to kEvent
	set |name| of myWakeEvent to "Monthly wake"
	set |date| of |trigger| of myWakeEvent to firstOfTheMonth
	set |type| of |action| of myWakeEvent to "start up or wake"
	set |uniqueid| of myWakeEvent to "monthly-wake"
	tell scheduler to add event myWakeEvent

	–– Schedule a shut down event
	set myShutdownEvent to kEvent
	set |name| of myShutdownEvent to "Monthly shut down"
	set |date| of |trigger| of myShutdownEvent to (firstOfTheMonth + kShutdownAfterSecondsFromWaking)
	set |type| of |action| of myShutdownEvent to "shutdown"
	set |uniqueid| of myShutdownEvent to "monthly-shutdown"
	tell scheduler to add event myShutdownEvent

	–– Clean up; not required
	quit

end tell